# Mp3tag (v2.33) Parsing for Amazon Web Service (french) 
#
# 14.11.2005 begonnen von dano
# 24.11.2005 erweitert von Florian
# 03.12.2005 verbesserte Erkennung des Publishers
# 19.04.2006 Transformed to french amazon website by fx
#
# Speichern Sie diese Datei im Mp3tag Datenverzeichnis unter
# C:\Dokumente und Einstellungen\*Benutzername*\Anwendungsdaten\Mp3tag\data\sources
#
#
#
[Name]=Amazon.fr
[BasedOn]=http://webservices.amazon.fr
[IndexUrl]=http://www.amazon.fr/exec/obidos/search-handle-url/index%3Dmusic-tracks-fr%26field-keywords%3D%s/ref%3Dpd%5Frhf%5Fs%5F1/402-9351308-6172941
[AlbumUrl]=
[WordSeperator]=%20
[IndexFormat]=%_url%|%_preview%|%album%|%date_released%|%artist%
[SearchBy]=$lower(%title%)

[ParserScriptIndex]=...

# ###################################################################
# This script parses the webpage for all releases
# by this albumname.
#
# The output format is defined by IndexFormat above, which
# is used by the selection dialog
# ###################################################################
debug "on" "c:\\debug_One_AmazonFr_A.html" "20"

moveline 5

if "R"

	#MULTIPLE RESULTS
	
	do
	 	findline "<td width=100% class=\"small\">"
		Moveline 1
	 	
	 	#URL
	 	say "http://webservices.amazon.fr/onca/xml?Service=AWSECommerceService&AWSAccessKeyId=045ZGZ60B4A7NQEJRMR2&Operation=ItemLookup&ItemId="
	 	findinline "ASIN/" 
	 	sayuntil "/"
	 	say "&ItemPage=1&ResponseGroup=ItemAttributes,Small,Tracks,Images"
	 	say "|"
	 	
	 	#PREVIEW
	 	say "http://www.amazon.fr"
	 	findinline "href=" -1
	 	movechar 6
	 	sayuntil "><b> "
	 	say "|"
	 	
	 	#ALBUM
	 	findinline "<b> "
	 	sayrest
	 	say "|"
	 	
	 	#RELEASE DATE
	 	moveline 2
	 	if "("
	 		findinline "("
	 		sayuntil ")"
	 	moveline 1
	 	else
	 		say "inconnue"
	 	endif
	 	say "|"
	 	
	 	#ARTIST
	 	findinline "<br> "
	 	sayuntil "("
	 	
	 	saynewline
	 	findline "</table>" 2 	
	 	moveline 2
	 	
	while "<table width=100%>"

else

	#SINGLE RESULT
	
	findline "ASIN/"
 	
 	#URL
 	say "http://webservices.amazon.fr/onca/xml?Service=AWSECommerceService&AWSAccessKeyId=045ZGZ60B4A7NQEJRMR2&Operation=ItemLookup&ItemId="
 	findinline "ASIN/" 
 	sayuntil "&"
 	say "&ItemPage=1&ResponseGroup=ItemAttributes,Small,Tracks,Images"
 	say "|||||"
 	
endif

[ParserScriptAlbum]=...

# ###################################################################
# This script parses the albums page for all common information.
#
# The current output variable is set via the outputto command
# All these fields are used by the confirm online information dialog
# ###################################################################
debug "on" "c:\\debug_One_AmazonFr_B.html" "20"

# CoverURL
outputto "coverurl"
findinline "<LargeImage>"
findinline "<URL>"
sayuntil "</URL>"

findinline "<ItemAttributes>"

# Artist
outputto "artist"
findinline "<Artist>"
sayuntil "</Artist>"

# Publisher
outputto "publisher"
findinline "</EAN>"
if "<Label>"
	findinline "<Label>"
	sayuntil "</Label>"
endif

# Year
outputto "year"
findinline "<ReleaseDate>"
saynextnumber

# Album
outputto "album"
findinline "<Title>"
sayuntil "</Title>"