# Mp3tag parsing for Metal-Archivs.com, created by mayhemer on 2009-02-18

# Save it in your Mp3tag data directory, i.e.
# C:\Documents and Settings\*username*\Application Data\Mp3tag\data\sources

# - Search for releases by album name
#
# Supported Tags:
#   Artist, Album, Year, Title, Track
#   Cover
#

[Name]=Metal Archives
[BasedOn]=www.metal-archives.com
[IndexUrl]=http://www.metal-archives.com/search.php?string=%s&type=album
[AlbumUrl]=http://www.metal-archives.com/release.php?id
[WordSeperator]=+
[IndexFormat]=%Artist%|%_url%|%Album%
[SearchBy]=%album%


[ParserScriptIndex]=...
# ###################################################################
#					I  N  D  E  X
# ###################################################################
#debug "on" "d:\\debug_MetalArchive.log" "10"

findline "release.php?id="
If "<script language='JavaScript'>"
	say "|"
	findInLine "release.php?id"
	sayUntil "'"
	say "|"
else
	Replace "<strong>" ""
	Replace "</strong>" ""
	RegexpReplace "\([A-Za-z]{2,3}\)" ""
	do
		findInLine "band.php?id="
		findInLine ">"
		sayUntil "<"
		say "|"
		findInLine "release.php?id"
		sayUntil "'"
		say "|"
		findInLine ">"
		sayUntil "</a>"
		findInLine "</tr>"
		saynewline
	while "<tr>"
endif

[ParserScriptAlbum]=...
# ###################################################################
#					A  L  B  U  M
# ###################################################################
#debug "on" "d:\\debug_MetalArchive_Album.log" "10"

# Artist
outputto "Artist"
findline "<title>"
RegexpReplace "\([A-Za-z]{2,3}\)" ""
findinline "Encyclopaedia Metallum - "
sayuntil " - "

# Album
outputto "Album"
findinline " - "
sayuntil "</title>"

# Publisher
outputto "Publisher"
findline "<tr><td colspan='2' class='tt'>"
MoveLine 1
findLine "<br>"
findInLine "</b>, "
sayUntil "<br>"

# Year
outputto "Year"
findLine "</td>"
findInLine "<b>"
sayUntil "</b>"

# Tracks
outputto "Tracks"
findLine "<tr><td>1.</td><td>"
do
	findinline ".</td><td>"
	sayuntil "</td>"
	say "|"
	findinline "</tr>"
	
while "<tr><td>"

# Coverurl
findline "<img"
findinline "src='"
if "http"
    outputto "coverurl"
    sayuntil "'"
endif