# ###################################################################
# Mp3tag (v2.33 or higher) parsing for discogs.com
# Created by freak on 2009-10-02
# Visit: www.torrentech.org - best electronic site ever!
# 
# This file should be in your sources directory. On Windows XP it's:
# C:\Documents and Settings\*username*\Application Data\Mp3tag\data\sources
# 
# Get the url of the release in discogs, and get the release number
# ie. http://www.discogs.com/release/23455   (you need the 23455)
# ###################################################################

[Name]=Discogs Release ID
[BasedOn]=http://www.discogs.com
[IndexUrl]=http://api.discogs.com/release/%s?f=xml
[AlbumUrl]=http://www.discogs.com
[Encoding]=utf-8
[WordSeperator]=
[IndexFormat]=%_url%
[SearchBy]=%discogs-id%

[ParserScriptIndex]=...
# ###################################################################
#					I  N  D  E  X
# ###################################################################
sayoutput "CurrentUrl"
unspace

[ParserScriptAlbum]=...
# ###################################################################
#					A  L  B  U  M
# ###################################################################
# debug "on" "C:\debug_ID.txt"

joinuntil "</resp>"
regexpreplace "<id>\d+?</id>" ""									# added by pone
replace "|" "&#166;"
regexpreplace "\s\x{2153}" ""
regexpreplace "<label catno=\"([^\"]*?)\" name=\"([^\"]*?) \(\d+\)\" />" "<label catno=\"\1\" name=\"\2\" />"
regexpreplace "<name>([^\"]*?) \(\d+\)</name>" "<name>\1</name>"
regexpreplace "status=\"([^\"]*?)\">" "status=\"fuckyou\">"
regexpreplace "<track><position><title>([^\"]*?)</title><duration></track>" ""
regexpreplace "<track><position><title>([^\"]*?)<duration></track>" ""
regexpreplace "<duration>([^\"]*?)</duration>" ""
regexpreplace "<track><position /><title>([^\"]*?)</title><duration /></track>" ""
replace "<track><position /><title /><duration /></track>" ""
replace "<duration />" ""
regexpreplace "<([a-z]+) />" ""

#WWWAUDIOFILE
outputto "wwwaudiofile"
findinline "release id=\""
say "http://www.discogs.com/release/"
saynextnumber

#DISCOGS-ID
gotochar 1
outputto "discogs-id"
findinline "release id=\""
saynextnumber

#COVERURL
findinline "status=\"fuckyou\">"
if "<images>"
	outputto "coverurl"
	findinline "uri="
	if "\""
    	movechar 1
    	sayuntil "\""
	endif
endif

#ARTIST/BAND
regexpreplace "<name>([^\"\<]*?)</name><anv>([^\"\<]*?)</anv>" "<name>\2</name>"
replace "</name><join>" " "
replace "</join></artist><artist><name>" " "
findinline "<tracklist>"
findinline "</title>"
ifnot "<artists>"
	gotochar 1
	outputto "Artist"
	findinline "<artist><name>"
	sayuntil "</name>"
else
	gotochar 1
	outputto "Band"
	findinline "<artist><name>"
	sayuntil "</name>"
endif

#ALBUM
gotochar 1
outputto "album"
findinline "<title>"
sayuntil "</title>"

#CATALOG#
outputto "Catalog #"
findinline "catno=\""
sayuntil "\" "

#PUBLISHER
outputto "publisher"
findinline "name=\""
sayuntil "\" />"

#COMMENT
gotochar 1
outputto "comment"
findinline "catno=\""
findinline "name=\""
sayuntil "\" />"
say " ("
gotochar 1
findinline "catno=\""
sayuntil "\" "
say ")"

#MEDIATYPE
outputto "Media type"
replace "</description><description>" ", "
replace " qty=\"1\"" ""
replace " />" "/>"
regexpreplace "<format name=([^/]*?)/>" "<format name=\1></format>"
regexpreplace "<format name=\"([^\"]*?)\" qty=\"(\d+)\">" "<format name=\"\2 x \1\">"
findinline "<format name=\""
sayuntil "\""
ifnot "\"></format>"
say ", "
findinline "><description>"
sayuntil "</description>"
endif
findinline "</format>"
ifnot "</formats>"
    do
        say " / "
        findinline "<format name=\""
        sayuntil "\""
		findinline ">"
		ifnot "</format></formats>"
			ifnot "\"></format>"
				say ", "
				findinline "<description>"
				sayuntil "</description>"
			endif
		endif
        findinline "</format>"
    while "<format "
endif

#COUNTRY
outputto "country"
findinline "</styles>"
if "<country>"
	findinline "<country>"
	sayuntil "</country>"
endif

#DATE
gotochar 1
findinline "</styles>"
if "<country>"
	findinline "</country>"
endif
if "<released>"
	outputto "Date"
	findinline "<released>"
	sayuntil "</released>"
endif

#ORIGYEAR
gotochar 1
findinline "</styles>"
if "<country>"
	findinline "</country>"
endif
if "<released>"
	outputto "Origyear"
	findinline "<released>"
	sayuntil "</released>"
endif

#YEAR
gotochar 1
regexpreplace "<released>(\d{4,})/(\d\d)/(\d\d)</released>" "<released>\1/\2</released>"
findinline "</styles>"
if "<country>"
	findinline "</country>"
endif
if "<released>"
	outputto "Year"
	findinline "<released>"
	sayuntil "</released>"
endif

#STYLES (all)
outputto "Genre"
replace "</style><style>" ", "
findinline "<style>"
sayuntil "</style>"

#VINYL#
gotochar 1
regexpreplace "<position>\d+</position>" "<position></position>"
regexpreplace "<position>AA(\d*?)</position>" "<position>B\1</position>"
regexpreplace "<position>AAA(\d*?)</position>" "<position>C\1</position>"
regexpreplace "<position>AAAA(\d*?)</position>" "<position>D\1</position>"
regexpreplace "<position>X(\d*?)</position>" "<position>A\1</position>"
regexpreplace "<position>Y(\d*?)</position>" "<position>B\1</position>"
regexpreplace "<position>([a-zA-Z^\d])</position>" "<position>\11</position>"
regexpreplace "<position>(\d+)-(\d+)</position>" "<position></position>"
findinline "<tracklist><track>"
ifnot "<position></position>"
	outputto "Vinyl#"
	do
	    findinline "<position>"
	    sayuntil "</position>"
	    say "|"
	    findinline "</track>"
	while "<track>"
endif

#ARTIST
gotochar 1
findinline "<tracklist>"
do
    findinline "</title>"
    if "<artists>"
		outputto "Artist"
        findinline "<name>"
        sayuntil "</name>"
    	say "|"
    endif
    findinline "</track>"
while "<track>"

#TRACKS
gotochar 1
outputto "Tracks"
findinline "<tracklist>"
do
    findinline "<title>"
    sayuntil "</title>"
	findinline "<position>" -1
	findinline "<position>"
	ifnot "</position>"
		say " "
		sayuntil "</position>"
	endif
    say "|"
    findinline "</track>"
while "<track>"

#CREDITS
gotochar 1
regexpreplace "<anv>[^<]*?</anv>" ""
regexpreplace "(<name>[^<]*?</name>)(<role>[^<]*?</role>)" "\2\1"
regexpreplace "<tracks>([^<]*)</tracks>" " (Tracks: \1)"
replace "</role><name>" ": "
replace "</artist><artist>" "; "
replace "<role>" ""
replace "</name>" ""
findinline "</labels>"
if "<extraartists>"
	outputto "credits"
	findinline "<extraartists><artist>"
	sayuntil "</artist></extraartists>"
endif

#NOTES
gotochar 1
regexpreplace "\>\.\<" ". "
regexpreplace "\>\,\<" ", "
findinline "</styles>"
if "<country>"
	findinline "</country>"
endif
if "<released>"
	findinline "</released>"
endif
if "<notes>"
	findinline "<notes>"
	outputto "notes"
	sayuntil "</notes>"
endif

#MIXARTIST
gotochar 1
findinline "<tracklist>"
do
	findinline "</title>"
	if "<artists>"
		findinline "</artists>"
	endif
	if "<extraartists>"
	replace "<resp stat" "xxxrespstat"
	replace "<extraartists>" "<xextraartistsx>"
	endif
	findinline "</track>"
while "<track>"
gotochar 1
if "x"
	outputto "Mixartist"
	regexpreplace "\s+\[[^<]*?\]" ""
	findinline "<tracklist>"
	do
		findinline "</title>"
		if "<artists>"
			findinline "</artists>"
		endif
		if "<xextraartistsx>"
			findinline "<artist>"
			sayuntil "</artist>"
		endif
		say "|"
		findinline "</track>"
	while "<track>"
endif