.:: DJ BEATPORT SCRIPT 2012 by Asse Dj ::., The best and complete script for dj that use beatport for taggin Options

[Norbornano]

Complete script for beatport DJ User

Cover
Artist / Authors
Title
Remixer | mixartist
Album Artist
Release / Album
Genre
Label / Publisher
Album
Description
BPM
Bitrate
Track / #
Year (yyy-mm-dd) It's the Realease Date on Beatport
Discnumber
Comment
KEY CAMELOT (used for MixedInKey 5.0)
Key Lyrics
catalog #
discogs_catalog
Composer (Complete descriction of the album - From Beatport)

CODE

[Name]=beatport.com
[BasedOn]=http://api.beatport.com
[IndexUrl]=http://api.beatport.com/catalog/search?v=2.0&perPage=50&format=xml&query=%s&facets[]=fieldType:release
[AlbumUrl]=http://api.beatport.com/catalog/releases/detail?v=1.0&format=xml&id=
[WordSeperator]=+
[IndexFormat]=%_url%|%_preview%|%Artists%|%Album%|%Released%|%Label%|%Catalog%
[SearchBy]=%artist% %album%
[ParserScriptIndex]=...
#Debug "on" "K:\ParserScriptIndex.txt" 4
Replace "|" "/"
FindLine "<document"
    Do
    JoinUntil "</document>"
    RegexpReplace "\s+\B" ""
    SayRegExp "(?<=\")\d+(?=\"><i)"
    Say "|"
    Say "http://www.beatport.com/release/"
    SayRegExp "(?<=lName>).+(?=</u)"
    Say "/"
    SayRegExp "(?<=\")\d+(?=\"><i)"
    Say "|"
    FindInLine "<performer ref=\"Artist\""
    FindInLine "<name>"
    SayUntil "</"
    SayUntil "</"
        
    FindInLine "</performer>"
    if "<performer ref=\"Artist\""
        Say ", "
        FindInLine "<name>"
        SayUntil "</"
        FindInLine "</performer>"
        if "<performer ref=\"Artist\""
            Say ", and more..."
        endif
    endif
        
    Say "|"
    Gotochar 1
    FindInLine "<name>"
    if "</"
        Say "...empty.tag..."
    else
        Gotochar 1
        SayRegExp "(?<=<name>).+(?=</name><urlName>)"
    endif
    Say "|"
    SayRegExp "(?<=sed>).+?(?=</da)"
    Say "|"
    SayRegExp "((?<=l id=\"\d{3}\"><name>)|(?<=l id=\"\d{4}\"><name>)|(?<=l id=\"\d{5}\"><name>)).+?(?=</name></l)"
    Say "|"
    SayRegExp "(?<=er>).+?(?=</c)"
    MoveLine 1
    Saynewline
    Unspace
While "<document"

[ParserScriptAlbum]=...

#debug "on" "K:\ParserScriptAlbum.txt"

outputto "coverurl"
#findline "width=\"60\" height=\"60\" ref=\"release\""
findline "width=\"60\" height=\"60\" ref=\""
MoveLine 1
SayRegexp "http.+?jpg"
#SayRegexp "(?<=<image url=\").+?(?=\" width=\"\d{3}\" height=\"\d{3}\" ref=\"release\"/>)"
#SayRegexp "(?<=<image url=\").+?(?=\" width=\"\d{3}\")"


outputto "album"
findline "<name>"
FindInLine "<name>"
SayUntil "</"

outputto "year"
findline "<dateReleased>"
# regexpreplace "<dateReleased>(\d{4})-(\d{2})-(\d{2})</dateReleased>" "<dateReleased>$1-$2-$3</dateReleased>"
FindInLine "<dateReleased>"
SayUntil "</"

outputto "releasetime"
Sayoutput "year"
SayUntil "</"

outputto "discogs_catalog"
findline "<catalogNumber>"
FindInLine "<catalogNumber>"
SayUntil "</"

# outputto "comment"
# findline "<description>"
# FindInLine "<description>"
# SayUntil "</"

outputto "composer"
findline "<description"
joinuntil "</description>"
FindInLine "<description>"
SayUntil "</"

outputto "catalog #"
Sayoutput "discogs_catalog"

outputto "publisher"
findline "<label"
findline "<name>"
FindInLine "<name>"
SayUntil "</"

outputto "albumartist"
findline "<performer ref=\"Artist\""
joinuntil "</performer>"
FindInLine "<name>"
SayUntil "</"

MoveLine 1
Unspace
if "<performer ref=\"Artist\""
    joinuntil "</performer>"
    Say " & "
    FindInLine "<name>"
    SayUntil "</"
    MoveLine 1
    Unspace
    if "<performer ref=\"Artist\""
        set "albumartist", "Various Artists"
    endif
endif
replace "|" "/"


findline "<track"
do
    outputto "tracks"
    findline "<name>"
    FindInLine ">"
    SayUntil "</"
    findline "<mixName>"
    FindInLine ">"
    if "Original Mix"
        Say "|"
    else
        Say " ("
        SayUntil "</"
        Say ")|"
    endif
    
    outputto "_length"
    findline "<trackLength>"
    FindInLine ">"
    SayUntil "</"
    Say "|"
    
    # outputto "bpm"
    # findline "<trackBpm>"
    # FindInLine ">"
    # SayUntil "</"
    # Say "|"

    outputto "unsyncedlyrics"
    findline "<trackKey>"
    joinuntil "</trackKey>"
    FindInLine "<standard>"
    joinuntil "</standard>"
    FindInLine "<letter>"
    SayUntil "</"
    FindInLine "<sharp>"
        if "1"
            Say "-Sharp"
        else
            SayUntil "</"
        endif
    FindInLine "<flat>"
        if "1"
            Say "-Flat"
        else
            SayUntil "</"
        endif
    Say " "
    FindInLine "<chord>"
        if "minor"
            Say "Minor"
        endif
        if "major"
            Say "Major"
        endif
    Say "|"
    
    outputto "genre"
    findline "<genre"
    joinuntil "</genre>"
    FindInLine "<name>"
    SayUntil "</"
    Say "|"
    
    findline "<performer"
    Unspace
    joinuntil "</track>"
    regexpreplace ">\s+<" "><"
    regexpreplace "<performer ref=\"([^\"]+)\"[^>]+><name>([^\"]+)</name></performer>" "<$1>$2"
    outputto "artist"
    Sayregexp "(?<=<Artist>)[^<]+" ", " "</track>"
    Say "|"
    
    Gotochar 1
    outputto "mixartist"
    Sayregexp "(?<=<Remixer>)[^<]+" ", " "</track>"
    Say "|"
    
    MoveLine 1
    Unspace
    
while "<track"

p.s. for best results use columns.ini inside software

This post has been edited by Norbornano: Mar 25 2013, 14:50

Attached File(s)

 Beatport.1.0.zip ( 15.26K ) Number of downloads: 368

 

[Norbornano]

.

This post has been edited by Norbornano: Mar 25 2013, 12:41

Attached File(s)

 Beatport.1.1.zip ( 16.39K ) Number of downloads: 115

 

[stevehero]

.

THANKS for ripping off most, if not all of 'beatport-1.5 by jaimz' scripts not giving credit. You even label yours as v1.1 when inside the script its '# version 1.5' Just a slight give away that you put no effort whatsoever into these scripts. And also using my camelot code.

I don't know what the forum rules are on plagiarizing other peoples hard work but this is a good example.

Original version found here:  beatport_1.5_by_jaimz.zip ( 2.6K ) Number of downloads: 11


This post has been edited by stevehero: May 11 2013, 16:08